10 ' El CASTILLO DEL REY CERINO
20 '
30 '   POR PABLO QUINTERO FDZ.
40 '
50 KEY DEF 70,0,0:KEY DEF 66,0,0:ON BREAK CONT:SPEED KEY 255,255
60 POKE &BDEE,201:DEFINT a-z
70 DIM habit$(19),mapa(19,6),objeto(19,9),examen(19,52,2),examen$(19,60),vocabj$(52),acceso(19)
80 s1=(time3+TIME)/300:hab=1:PAPER 0:INK 0,0:BORDER 0:INK 1,15:INK 2,6:INK 3,7:MODE 1:GOSUB 2210
90 WINDOW #0,1,40,1,22:WINDOW #1,1,40,23,25:LOCATE #1,1,1:PRINT #1,STRING$(39,154):PRINT#1:PRINT #1,STRING$(39,154)
100 PEN 2:LOCATE 6,2:PRINT "EL CASTILLO DEL REY CERTINO":PEN 1:LOCATE 17,4:PRINT "POR:":PEN 3:LOCATE 9,6:PRINT "Pablo Quintero Fdz."
:PRINT:PRINT:GOTO 1360
110 ' ** ** MOVIMIENTO ** **
120 IF cod(0)=99 THEN PRINT:PEN 3:PRINT "[Hasta otra!":FOR a=1 TO 3000:NEXT:CALL 0
130 cpr=4:IF cod(0)=43 THEN 1360
140 IF hab=1 AND cod(0)=5 AND cod(1)=41 THEN hab=2:GOTO 1360 
150 PEN 3:IF cod(0)>6 THEN 200
160 IF cod(0)=0 THEN PRINT:PRINT "Eso no significa nada.":GOTO 1520
170 IF mapa(hab,cod(0))=0 THEN PRINT:PRINT "En esa direccion no puedo ir.":GOTO 1520
180 IF mapa(hab,cod(0))=50 THEN PRINT:PRINT "La puerta esta cerrada.":GOTO 1520
190 hab=mapa(hab,cod(0)):GOTO 1360
200 ' ** ** COGER ** **
210 IF cod(0)<>7 THEN 300
220 IF cod(1)=50 AND hab=7 THEN PRINT:PRINT "Es del rey.  No creo que sea una buena  idea ya que podrian delatarte.":GOTO 1520
230 IF cod(1)=0 THEN PRINT:PRINT "]Que cojo?":GOTO 1520
240 FOR a=1 TO 8:IF objeto(hab,a)<>cod(1) THEN NEXT a:PRINT:PRINT "Eso no lo veo.":GOTO 1520
250 FOR b=1 TO 4:IF llevas(b)=0 THEN llevas(b)=cod(1) ELSE NEXT b:PRINT:PRINT "Llevas demasiadas cosas.":GOTO 1520
260 objeto(hab,a)=objeto(hab,a+1):IF objeto(hab,a)<>0 THEN a=a+1:GOTO 260 ELSE objeto(hab,a)=0
270 IF cod(1)=24 THEN esc=1
280 IF cod(1)=30 THEN com=1
290 PRINT:PRINT "Hecho.":GOTO 1520
300 ' ** ** DEJAR ** **
310 cond3=0:cond4=0:IF cod(0)<>8 THEN 390
320 IF cod(1)=30 THEN com=0 ELSE IF cod(1)=24 THEN esc=0
330 cond3=cond3+1:IF llevas(cond3)=0 THEN PRINT "Eso no lo tienes.":GOTO 1520
340 IF llevas(cond3)<>cod(1) THEN 330
350 cond4=cond4+1:IF objeto(hab,cond4)=0 THEN objeto(hab,cond4)=cod(1) ELSE GOTO 350
360 llevas(cond3)=0
370 IF llevas(cond3+1)<>0 THEN llevas(cond3)=llevas(cond3+1):cond3=cond3+1:GOTO 370
380 llevas(cond3)=0:PRINT:PRINT "Ya no lo tengo.":cond2=cond2-1:GOTO 1520
390 ' ** ** ABRE PUETAS ** **
400 contd=0:IF cod(0)<>9 OR cod(1)<>20 THEN 490
410 IF hab=1 THEN PRINT:PRINT "Eso es imposible.La puerta es enorme y  desde afuera no se puede abrir.":GOTO 1520
420 IF hab=5 OR hab=9 OR hab=8 OR hab=10 OR hab=13 THEN 440 ELSE GOTO 430
430 IF hab=6 OR hab=7 OR hab=11 OR hab=14 THEN PRINT:PRINT "Ya esta abierta.Estas dentro del cuarto.":GOTO 1520 ELSE PRINT:PRINT "Aq
ui no hay ninguna puerta.":GOTO 1520
440 contd=contd+1:IF contd=9 THEN 450 ELSE IF llevas(contd)<>28 THEN 440 ELSE GOTO 460 
450 PRINT:PRINT "No tienes las llaves.":GOTO 1520
460 ca=0:FOR a=1 TO 6:IF mapa(hab,a)=50 THEN ca=a
470 NEXT:IF ca=0 THEN PRINT:PRINT "La puerta ya la habias abierto.":GOTO 1520
480 mapa(hab,ca)=acceso(hab):PRINT:PRINT "Ok!":hab=acceso(hab):GOTO 1360
490 ' ** ** CERRAR PUERTAS ** **
500 IF cod(0)<>10 THEN 520
510 PRINT:PRINT "No es necesario.":GOTO 1520
520 ' ** ** EXAMINAR ** **
530 IF cod(0)<>12 THEN 610
540 IF cod(1)=31 AND pri2=1 THEN PRINT:PRINT "Se ha enamorado de ti.":GOTO 1520
550 IF cod(1)=0 THEN PRINT:PRINT "Dime lo que he de examinar.":GOTO 1520
560 IF examen(hab,cod(1),1)=-1 THEN PRINT:PRINT "No le encuentro nada especial.":GOTO 1520
570 IF examen(hab,cod(1),2)=cod(1) THEN PRINT:PRINT examen$(hab,cod(1)) ELSE PRINT:PRINT "Eso no lo veo."
580 IF examen(hab,cod(1),1)<>0 THEN objeto(hab,1)=examen(hab,cod(1),1)
590 IF examen(hab,cod(1),1)<>0 THEN examen(hab,cod(1),1)=-1
600 GOTO 1520
610 ' ** ** INVENTARIO ** **
620 con=0:IF cod(0)<>16 THEN 660
630 IF llevas(1)=0 THEN PRINT:PRINT "No llevas nada"; ELSE PRINT:PRINT "Llevas ";
640 con=con+1:IF llevas(con)=0 THEN PRINT ".":GOTO 1520 ELSE IF con<>1 THEN PRINT ",";
650 PRINT vocabj$(llevas(con));:GOTO 640
660 ' ** ** MATAR ** **
670 IF cod(0)<>14 THEN 780
680 esp=0:FOR a=1 TO 9:IF llevas(a)=23 THEN esp=1
690 NEXT:IF esp=1 AND hab=19 AND cen=0 THEN cen=1:PRINT:PRINT " Le das con la espada en la cabeza. El  centinela grita ARGHSS!!...la
 sangre le corre por la frente, esta muerto.":examen(19,25,2)=25:examen$(19,25)="Esta muerto.":GOTO 1520
700 IF esp=0 AND hab=19 AND cen=0 THEN PRINT:PRINT "  Intentas matarlo pero el centinela se despierta y te atraviesa con su espada."
:GOTO 2620
710 IF cen=1 AND hab=19 THEN PRINT:PRINT "Ya esta suficientemente muerto.":GOTO 1520
720 IF cod(1)=39 AND hab=18 THEN PRINT:PRINT "No me atrevo.":GOTO 1520
730 IF cod(1)=40 AND hab=16 AND leon=0 THEN PRINT:PRINT "No hace falta esta dentro de la celda.":GOTO 1520
740 IF cod(1)=25 AND hab=3 THEN PRINT:PRINT "Mejor sera dejarlo descansar.":GOTO 1520
750 IF cod(1)=25 OR cod(1)=40 OR cod(1)=31 OR cod(1)=39 THEN PRINT:PRINT "No puedo, aqui no esta.":GOTO 1520
760 IF cod(1)=0 THEN PRINT:PRINT "]A quien mato?":GOTO 1520 
770 PRINT:PRINT "Eso no se puede matar.":GOTO 1520 
780 ' ** ** ACCIONAR ** **
790 IF cod(0)<>15 OR hab<>19 THEN 880
800 IF cen=0 THEN PRINT:PRINT "El centinela se despierta y te          atraviesa con su espada.":GOTO 2620
810 IF cod(1)=29 THEN PRINT:PRINT "Hay tres palancas.":GOTO 1520
820 IF cod(2)<>29 THEN PRINT:PRINT "Yo si que te voy a accionar a ti.":GOTO 1520
830 IF cod(1)=36 AND dra=0 THEN dra=1:GOTO 870
840 IF cod(1)=37 AND leo=0 THEN leo=1:GOTO 870
850 IF cod(1)=38 AND pri=0 THEN pri=1:GOTO 870
860 PRINT:PRINT "Esa palanca ya la has accionado.":GOTO 1520
870 PRINT:PRINT "Hecho.Se oye un ruido en las celdas.":GOTO 1520
880 '** ** DAR COMIDA
890 IF COD(0)<>49 THEN 930
900 IF cod(1)=30 AND cod(2)=0 THEN PRINT:PRINT "A quien le doy la comida.":GOTO 1520
910 IF cod(1)=30 AND cod(2)=31 AND com=1 THEN PRINT:PRINT "Devora la pata de cordero con mucho     enfasis,se deja un poco.":pri3=6:
COD(0)=8:COD(1)=30:GOTO 300
920 IF cod(1)=30 AND cod(2)=31 AND com=0 THEN PRINT:PRINT "No tienes nada de comida.":GOTO 1590
930 ' SALIDAS
940 IF cod(0)<>60 THEN 1040
950 PRINT:FOR ac=1 TO 6:IF mapa(hab,ac)=0 THEN 1020
960 s=1:IF ac=1 THEN PRINT "Norte ";
970 IF ac=2 THEN PRINT "Sur ";
980 IF ac=3 THEN PRINT "Este ";
990 IF ac=4 THEN PRINT "Oeste ";
1000 IF ac=5 THEN PRINT "Arriba ";
1010 IF ac=6 THEN PRINT "Abajo ";
1020 NEXT AC:IF s=0 THEN PRINT "Tienes que averiguar como puedo entrar."
1030 s=0:PRINT:GOTO 1520
1040 ' DISCO SAVE LOAD
1050 IF cod(0)=107 THEN 1170
1060 IF cod(0)=106 THEN 1070 ELSE GOTO 1270
1070 'LOAD
1080 CAT:PRINT "Dame el fichero a cargar:";:INPUT "",nomb$
1090 IF nomb$="" THEN 1360
1100 OPENIN nomb$+".CRC"
1110 INPUT #9,hab,pri2,esc,cen,cpr,com,esc,dra,leo,pri,turno,min2,hor2
1120 FOR a=1 TO 8:INPUT #9,llevas(a):NEXT
1130 FOR x=1 TO 19:FOR y=1 TO 6:INPUT #9,mapa(x,y):NEXT y,x
1140 FOR x=1 TO 19:FOR y=1 TO 9:INPUT #9,objeto(x,y):NEXT y,x
1150 FOR x=1 TO 19:FOR y=1 TO 52:INPUT #9,examen(x,y,1):NEXT y,x
1160 CLOSEIN:GOTO 1360
1170 'SAVE
1180 PRINT "Como le vas a llamar:";:INPUT "",nomb$
1190 IF LEN(nomb$)>8 THEN PRINT CHR$(11);:GOTO 1180
1200 min2=min1:hor2=hor:OPENOUT nomb$+".CRC"
1210 WRITE #9,hab,pri2,esc,cen,cpr,com,esc,dra,leo,pri,turno,min2,hor2
1220 FOR a=1 TO 8:WRITE #9,llevas(a):NEXT
1230 FOR x=1 TO 19:FOR y=1 TO 6:WRITE #9,mapa(x,y):NEXT y,x
1240 FOR x=1 TO 19:FOR y=1 TO 9:WRITE #9,objeto(x,y):NEXT y,x
1250 FOR x=1 TO 19:FOR y=1 TO 52:WRITE #9,examen(x,y,1):NEXT y,x
1260 CLOSEOUT:GOTO 1360
1270 ' PALABROTAS
1280 IF COD(0)>99 OR COD(1)>99 THEN 1290 ELSE GOTO 1350
1290 IF disc=1 THEN PRINT:PRINT "Otra vez no te lo consiento.":palab=4
1300 IF COD(0)=101 OR COD(1)=101 THEN PRINT:PRINT "Eso lo dices porque no estas en mi lugarsi lo estuvieses ya verias.":GOTO 1520
1310 palab=palab+1:IF palab=1 THEN PRINT:PRINT "No te pases que me enfadare.":GOTO 1520
1320 IF palab=2 THEN PRINT:PRINT "Te lo advierto, me estas cansando.":GOTO 1520
1330 IF palab=3 THEN PRINT:PRINT "Pero tu que te has creido. A la proxima me desconecto.":GOTO 1520
1340 IF palab>3 THEN PRINT:PRINT "[Adios!":FOR a=1 TO 4000:NEXT:CALL 0
1350 PRINT:PRINT "Haber si te explicas mejor.":GOTO 1520
1360 '-------- EXPLICA HABITACION ------
1370 PEN 1:PRINT:PRINT habit$(hab)
1380 IF hab=18 AND pri2=1 THEN PEN 3:PRINT:PRINT "El dragon esta fuera de la celda.La     princesa se muere chamuscada. Tu no     pu
edes soportarlo y te suicidas.":CALL &BB18:RUN
1390 IF pri2=1 THEN PRINT "La princesa Sheila esta aqui.":pri3=pri3+1
1400 IF objeto(hab,1)=0 THEN 1450
1410 contob=0:PEN 3:PRINT "Aqui hay:";
1420 contob=contob+1:IF objeto(hab,contob)=0 THEN PRINT ".":GOTO 1450
1430 IF contob<>1 THEN PRINT ",";
1440 PRINT vocabj$(objeto(hab,contob));:GOTO 1420
1450 IF hab=4 THEN GOTO 2620
1460 IF hab=1 AND cpr=4 THEN 2650
1470 IF hab=18 AND dra=1 THEN PEN 3:PRINT:PRINT "El dragon esta fuera de la celda. Te    coge con sus garras y te mata.":GOTO 2620
1480 IF hab=18 AND esc=1 THEN PEN 1:PRINT "Uf!.Menos mal que llevas el escudo y te ha protegido.":GOTO 1520 ELSE IF hab=18 AND esc=0
 THEN PEN 3:PRINT:PRINT "Te has chamuscado. Estas muerto.":GOTO 2620
1490 IF hab=17 AND pri=1 AND pri2<>1 THEN PEN 3:PRINT:PRINT "La princesa esta libre. Te besa y te    promete ir contigo hasta el fin
 del     mundo.":pri2=1:examen(17,35,1)=0:examen(17,35,2)=35:examen$(17,35)="Esta vacia.":GOTO 1520
1500 IF hab=16 AND leo=1 AND pri2=1 THEN PRINT "El leon esta fuera de la celda, os atacay mata a la princesa.   [[ No puedo     sopo
rtarlo !!,ha sido por mi culpa...   te matas.":CALL &BB18:RUN
1510 IF hab=16 AND leo=1 THEN PEN 3:PRINT:PRINT "El leon esta fuera de la celda, te atacay no te da tiempo a reaccionar.  Estas  mue
rto.":GOTO 2620
1520 '------- INPUT FRASE ---------
1530 s=(time3+TIME)/300-s1:m=s/60:h=m/60:minu=INT(h)*60:min1=INT(m-minu):hor=INT(h)
1540 PEN #1,1:LOCATE #1,1,2:PRINT #1,"Tiempo";:PEN #1,2:PRINT #1,USING "##:##";hor+hor2;min1+min2;
1550 PEN #1,1:PRINT #1,"  Habitacion:";:PEN #1,3:PRINT #1,hab;
1560 PEN #1,2:LOCATE #1,29,2:PRINT #1,"Turno:";:PEN #1,1:PRINT #1,turno:turno=turno+1
1570 IF pri3=5 THEN PEN 3:PRINT "Ya no aguanta mas y se desmaya.":GOTO 2620
1580 IF pri3>2 AND pri3<5 THEN PEN 3:PRINT "La princesa tiene mucha hambre."
1590 FOR a=0 TO 4:cod(a)=0:NEXT
1600 FOR a=1 TO 6:descom$(a)="":NEXT:PEN 2:PRINT
1610 INPUT "]y ahora";frase$:IF frase$="" THEN PRINT CHR$(11);:GOTO 1610
1620 IF JOY(0)=120 AND JOY(1)=120 THEN PRINT:PEN 3:PRINT " Me alegra que volvamos a vernos. Y seraun gran honor si el motivo es para
 ser  reparado por tu Gran Cerebro. Adelante  soy todo tuyo.":CALL &BB18:MODE 1:END
1630 b=1:pal=0:lo=LEN(frase$):FOR a=1 TO lo
1640 IF MID$(frase$,a,1)<>" " THEN 1670
1650 IF MID$(frase$,b,1)=" " THEN b=b+1:GOTO 1670
1660 descom$(pal)=UPPER$(MID$(frase$,b,a-b)):b=a+1:pal=pal+1:IF pal=6 THEN PEN 3:PRINT:PRINT "No te me enrolles.":GOTO 1600
1670 NEXT a:descom$(pal)=UPPER$(MID$(frase$,b,a-b))
1680 '
1690 '------- DICCIONARIO -------
1700 byc2=0:FOR byc=0 TO pal
1710 LE$=LEFT$(descom$(byc),1):niv=ASC(le$)-64
1720 IF niv<3 THEN RESTORE 1910:GOTO 1810
1730 IF niv<5 THEN RESTORE 1940:GOTO 1810
1740 IF niv<7 THEN RESTORE 1980:GOTO 1810
1750 IF niv<10 THEN RESTORE 2010:GOTO 1810
1760 IF niv<14 THEN RESTORE 2060:GOTO 1810
1770 IF niv<17 THEN RESTORE 2090:GOTO 1810
1780 IF niv<20 THEN RESTORE 2140:GOTO 1810
1790 IF niv<23 THEN RESTORE 2170:GOTO 1810
1800 RESTORE 2190
1810 READ pal$,nc
1820 IF pal$="-" THEN PEN 3:PRINT:PRINT "No comprendo la palabra ";descom$(byc);".":GOTO 1520
1830 IF descom$(byc)=pal$ AND nc=64 THEN 1860
1840 IF descom$(byc)=pal$ THEN cod(byc2)=nc:byc2=byc2+1:GOTO 1860
1850 GOTO 1810
1860 NEXT byc
1870 IF palab=0 THEN 110
1880 FOR a=0 TO 3:IF cod(a)=100 THEN PEN 3:GOTO 1270 ELSE NEXT
1890 IF cod(0)=102 THEN PEN 3:PRINT:PRINT "Esta bien. Pero no vuelvas a hacerlo.":disc=1:palab=0:GOTO 1520
1900 PEN 3:PRINT:PRINT "Creo que antes deberias disculparte por lo que me has dicho.":GOTO 1520
1910 ' A,B
1920 DATA "A",64,"AL",64,"ABRIR",9,"ABRE",9,"ABRO",9,"ABAJO",6,"ANALIZA",12,"ANALIZO",12,"ANALIZAR",12,"ACCIONA",15,"ACCIONAR",15,"A
LMOHADA",50,"ASQUEROSO",100,"ARRIBA",5
1930 DATA "BOTE",52,"BOLSA",48,"BAJA",6,"BAJO",6,"BAJAR",6,"BURRO",100,"-",0
1940 ' C,D
1950 DATA "COGER",7,"COGE",7,"COJO",7,"CERRAR",10,"CIERRA",10,"CIERRO",10,"CELDA",35,"COMER",13,"COME",13,"COMO",13,"COMETE",13,"CAM
A",22,"CENTINELA",25,"CUARTO",27,"COMIDA",30,"COCINA",26,"CASTILLO",42,"CAMA",46,"CANDELABRO",47,"CORREDOR",44,"CAPULLO"
1960 DATA 100,"CUARTO",50,"CAZOS",51,"CAZO",51,"CERDO",100,"COVARDE",101,"CARGAR",106
1970 DATA "DEJAR",8,"DEJA",8,"DEJO",8,"DESCRIPCION",43,"DESCRIBE",43,"DRAGON",39,"DAR",49,"DEL",64,"DISCULPAME",102,"DISCULPA",102,"
-",0
1980 ' E,F
1990 DATA "E",3,"ESTE",3,"EL",64,"ESCALERAS",33,"ESCONDERSE",11,"ESCONDETE",11,"EXAMINA",12,"EXAMINAR",12,"EXAMINO",12,"EX",12,"ESPA
DA",23,"ESCUDO",24,"ESTUPIDO",100,"ERES",64
2000 DATA "FIN",99,"-",0
2010 ' G,H,I
2020 DATA "GUARDIA",25,"GILIPOLLAS",100,"GILIPUERTAS",100,"GALLINA",101,"GRABAR",107
2030 DATA "HABITACION",50
2040 DATA "INVENTARIO",16,"I",16,"IR",64,"IDIOTA",100,"IMBECIL",100
2050 DATA "-",0
2060 ' J,K,L,M
2070 DATA "LA",64,"LAS",64,"LOS",64,"LLAVES",28,"LLAVE",28,"LIANAS",41,"LIANA",41,"LEON",40,"LOAD",106
2080 DATA "MATA",14,"MATO",14,"MATAR",14,"MAZMORRA",35,"MIRA",12,"MIRO",12,"MIRAR",12,"MESA",21,"MIEDOSO",101,"MIEDICA",101,"-",0
2090 ' N,O,P
2100 DATA "N",1,"NORTE",1
2110 DATA "O",4,"OESTE",4,"ORO",48
2120 DATA "PATA",30,"PUERTA",20,"PALANCA",29,"POR",64,"PRINCESA",31,"PASILLO",44,"PRIMERA",36,"PERDONA",102,"PERDONAME",102
2130 DATA "-",0
2140 ' Q,R,S
2150 DATA "RATA",32,"RATAS",32
2160 DATA "SHEILA",31,"SALIDA",60,"SALIDAS",60,"SALIR",60,"SILLA",45,"SILLAS",45,"SUBE",5,"SUBO",5,"SUBIR",5,"SUR",2,"S",2,"SEGUNDA"
,37,"SAVE",107,"-",0
2170 ' T,U,V
2180 DATA "TERCERA",38,"TONTO",100,"-",0
2190 ' W,X,Y,Z
2200 DATA "X",60,"-",0
2210 ' -------------------------- DATOS -----------------------
2220 RESTORE 2300:FOR a=1 TO 19
2230 READ a$:habit$(a)=a$:NEXT a
2240 FOR y=1 TO 19:FOR x=1 TO 6:READ nu:mapa(y,x)=nu:NEXT x,y
2250 objeto(12,1)=30:objeto(14,1)=24:objeto(11,1)=51:objeto(15,1)=52
2260 FOR a=1 TO 28:READ num,obj,ex,fr$:examen(num,ex,1)=obj:examen(num,ex,2)=ex:examen$(num,ex)=fr$:NEXT
2270 FOR c=1 TO 8:READ a,a$:vocabj$(a)=a$:NEXT c
2280 FOR buc=1 TO 5:READ a,b:acceso(a)=b:NEXT buc
2290 RETURN
2300 DATA "Estas en la entrada del castillo del ReyCertino Gaceto.Unas lianas cuelgan de   los torreones.La puerta esta cerrada."
2310 DATA "Estas encima del castillo.Al este hay uncentinela que no se percata de tu pre-  sencia. Tambien puedes ir al oeste o    b
ajar por unas escaleras."
2320 DATA "Aqui hay un guardia dormido.Puedes vol- ver atras."
2330 DATA "El guardia te ha visto. Se acerca y te  mata."
2340 DATA "Estas en un pasillo.Al oeste hay una    puerta.Puedes subir o ir al norte."
2350 DATA "Esta habitacion esta llena de ratas.Vas con cuidado para que no te muerdan.Hay  una mesa."
2360 DATA "Estas en el cuarto del rey Certino.Hay  una cama,la salida queda al  norte."
2370 DATA "Estas en un pasillo que va de este a    oeste. Al este hay una puerta."
2380 DATA "Al oeste del corredor puedes ver el     comedor.Al este continua el pasillo.Al  sur hay una puerta."
2390 DATA "Estas en el comedor.Hay una gran mesa   llena de sillas.Al norte hay una puerta y al este queda el pasillo."
2400 DATA "Estas en la cocina.Es enorme.Hay varios cazos.Al sur esta el comedor, al este   esta la despensa."
2410 DATA "Estas en la despensa.Hay comida para    varios dias."
2420 DATA "Estas en un dormitorio.No parece haber  nada de interes.Al este hay una puerta. Al sur esta el pasillo."
2430 DATA "Este cuarto no es muy grande y apenas   hay luz.Parece ser un desvan."
2440 DATA "Aqui hay unas escaleras que bajar. Al   oeste esta el pasillo."
2450 DATA "Estas en las mazmorras. Hay una celda.  Puedes ir al este.Las escaleras van     hacia arriba."
2460 DATA "Sigues en las mazmorras. Aqui hay otra  celda.Las salidas son norte,y oeste."
2470 DATA "Al norte hay un centinela... en esta    celda hay ... un dragon enorme...       [[[CUIDADO..TE ESCUPE FUEGO...!!!"
2480 DATA "Aqui hay un centinela. En la pared hay  tres palancas."
2490 DATA 0,0,0,0,0,0,0,1,4,3,0,5,0,0,2,0,0,0,0,0,0,0,0,0,8,0,0,50,2,0
2500 DATA 0,0,5,0,0,0,9,0,0,0,0,0,13,5,50,9,0,0,0,50,8,10,0,0
2510 DATA 50,0,9,0,0,0,0,10,12,0,0,0,0,0,0,11,0,0,0,8,50,0,0,0
2520 DATA 0,0,0,13,0,0,0,0,0,8,0,16,0,0,17,0,15,0,18,0,0,16,0,0
2530 DATA 19,17,0,0,0,0,0,18,0,0,0,0
2540 DATA 1,0,42,"Me da escalofrios.",1,0,41,"Parecen muy resistentes.",1,0,20,"Es de madera,muy grande.",2,0,25,"Esta despistado.",
3,28,25,"Tiene unas llaves.",5,0,20,"Es una puerta con cerrojo.",5,0,44,"Es un poco estrecho."
2550 DATA 2,0,33,"Van hacia abajo.",6,23,21,"Debajo hay una espada.",17,0,35,"Dentro esta la princesa Sheila. Te pide ayuda."
2560 DATA 16,0,40,"Esta muy furioso.",16,0,35,"Hay un leon dentro.",17,0,31,"Es bellisima, hay que salvarla por todoslos medios.",18
,0,35,"Esta el dragon.",18,0,39,"Es horrible,sera mejor que nos larguemos"
2570 DATA 10,0,45,"Todas las sillas son de madera.",10,0,20,"Parece dar a la cocina.",7,0,46,"Es muy comoda.",9,0,20,"Es la de la ha
bitacion del rey. Esta    cerrada.",7,48,22,"Debajo de la almohada hay una bolsa de  oro."
2580 DATA 19,0,25,"Esta echando una siesta,sera mejor no   hacer ruido.",10,47,21,"Es muy larga y hay un candelabro.",9,0,44,"Es de 
piedra,bastante estrecho."
2590 DATA 6,0,32,"Son repelentes.",8,0,44,"Tiene forma arqueada y es estrecho.",8,0,20,"Es de hierro.",19,0,29,"Parece que sirven pa
ra abrir las celdas.",11,0,51,"Los cazos estan vacios."
2600 DATA 23,"una espada",24,"un escudo",28,"unas llaves",30,"una pata de cordero",47,"un candelabro",48,"una bolsa de oro",51,"unos
 cazos",52,"un bote"
2610 DATA 5,6,9,7,8,15,13,14,10,11
2620 ' end
2630 PEN 2:PRINT:PRINT "Has fracasado, no podras casarte con la princesa Sheila. El malvado rey Certino que la tiene capturada en su
 castillo lamatara tarde o temprano."
2640 CALL &BB18:RUN
2650 ' Fin
2660 IF pri2=0 THEN PEN 3:PRINT:PRINT "No pensaras en irte sin la princesa,    ]verdad?":GOTO 1520
2670 FOR a=1 TO 9:IF llevas(a)=48 THEN 2680 ELSE NEXT:GOTO 2870
2680 CALL &BB18:PEN 3:PRINT:PRINT "[Felicidades!,  esta vez has resuelto la"
2690 PRINT "aventura sadisfactoriamente.Con la bolsa"
2700 PRINT "de oro que robaste al rey Certino ,  te "
2710 PRINT "puedes permitir una boda con la princesa"
2720 PRINT "Sheila de categoria. El resto del oro lo"
2730 PRINT "inviertes en un negocio de tendero.  Al "
2740 PRINT "al cabo de un a|o tu y Sheila teneis un "
2750 PRINT "hijo y le llamais Pablo. El negocio va  "
2760 PRINT "prosperando rapidamente. El rey Certino "
2770 PRINT "muere y compras el castillo. Vivis en el"
2780 PRINT "el resto de vuestra vida.":PRINT:CLEAR INPUT:CALL &BB18
2790 PEN 2:PRINT:PRINT:PRINT "   Fuisteis felices y no comisteis      "
2800 PRINT " perdices porque el negocio daba para    ":PRINT SPC(15);"caviar.":CLEAR INPUT:CALL &BB18
2810 MODE 0:fr1$="Y colorin colorado,":fr2$="esta aventura ya se":fr3$="    ha acabado."
2820 LOCATE 1,10:FOR a=1 TO 15:INK a,a+5:NEXT:FOR a=1 TO 20:c=INT(RND*14)+1:PEN c:PRINT MID$(fr1$,a,1);:NEXT a:PRINT:PRINT
2830 FOR a=1 TO 20:c=INT(RND*14)+1:PEN c:PRINT MID$(fr2$,a,1);:NEXT a:PRINT:PRINT
2840 FOR a=1 TO 20:c=INT(RND*14)+1:PEN c:PRINT MID$(fr3$,a,1);:NEXT a:CLEAR INPUT:CALL &BB18
2850 LOCATE 8,20:PEN 2:PRINT "Por:":PEN 12:PRINT:PRINT "Pablo Quintero Fdz."
2860 PEN 6:LOCATE 5,1:PRINT "El Castillo":PRINT:PRINT SPC(6);"del rey":PRINT:PRINT SPC(2);"Certino Gaceto":LOCATE 7,25:PEN 13:PRINT 
CHR$(164);:PEN 14:PRINT "1991":CLEAR INPUT:CALL &BB18:RUN
2870 PEN 3:PRINT:PRINT "[Felicidades!,conseguiste escapar con la"
2880 PRINT "princesa Sheila E.  Al cabo de un a|o te"
2890 PRINT "casaste con ella y tuvisteis un hijo que"
2900 PRINT "se llama Pablo.Sin embargo no conseguis-"
2910 PRINT "te acabar la aventura sadisfactoriamente"
2920 PRINT "ya que no teneis mucho dinero y no sois "
2930 PRINT "muy felices.":CALL &BB18:RUN